;============
;blueCube.orc
;============
sr=44100
kr=4410
ksmps=10
nchnls=2
;=====================
;Reverb initialization
;=====================
garvbsig init 0
;====================
;Delay initialization
;====================
gasig init 0
;==========================
;==========================
instr 1
i1=p5*.3
i2=p4*.98
i3=1/p3
i4=p5*.6
i5=p4
kfreq1=p6
kfreq2=p7
kamp2=p8
;================
;1 - Noise Branch
;================
a1 randi i4,p9
a1 oscil a1,i3,10
a1 oscil a1,3000,11
;=============
;2 - RM Branch
;=============
kamp1 linen kamp2,p3*.2,p3,p3*.2
asig1 oscil kamp1,kfreq1,11
asig2 oscil kamp2,kfreq2,3
aosc2=asig1*asig2
a2=aosc2*.085
;===================
;3 - Low Sine Branch
;===================
k3 oscil i4,i3,8
a3 oscil k3,i5,4
a3=a3*.5
;output to filter, reverb and panning
;====================================
iamp=p8*.4
aout=a1+a2+a3
kcf linseg 0,p3/2,850,p3/2,0
kpan oscil 1,0.1,17
alp butterlp aout, kcf
kenv linen iamp,p3*.8,p3,p3*.2
alpout=kenv*alp
outs alpout*kpan,alpout*(1-kpan)
garvbsig=garvbsig+(alpout*.2)
endin
;=========================
;=========================
instr 2
kfreq=p5
kramp linseg 0,p3*.8,p4,p3*.2,0
kenv1 linen p4,0,p3,10
anoise randi kramp,kenv1
aosc oscil anoise,kfreq,11
kpan oscil 1,.09,1
aosc2 reson aosc,kpan+100,100,2
outs aosc2*kpan,aosc2*(1-kpan)
garvbsig=garvbsig+(aosc2*.2)
endin
;=======================
;=======================
instr 3
kpan=p6
i1=p5*3
k1 oscil i1,1/p3,10
a2 oscil k1,p4,11
outs a2*kpan,a2*(1-kpan)
garvbsig=garvbsig+(a2*.1)
endin
;============================
;============================
instr 4
krt=p6 ;krt is the frq of randh output & clk osc
isd=p4 ;isd holds the value of the seed for randh
krnd randh 1000,krt,isd ;noise input to S&H
kclk oscil 100,krt,14 ;f14 is a duty cycle wave
ksh samphold krnd, kclk ;S&H
a2 oscil 600, ksh,11
a3 oscil a2,1/p3,10 ;f10=ADSR-a3 is the output
kpan oscil 1,.04,17
asig1=a3*kpan
asig2=a3*(1-kpan)
outs asig1,asig2
garvbsig=garvbsig+(a3*.2)
endin
;===============================
;INSTRUMENT 5 - FM w/reverse env
;===============================
instr 5
kcps=p4
kcar=p5
kmod=p6
kpan=p7 ;kpan determines pan position
kndx=p8
kamp=p9
krvb=p10
afm foscili kamp,kcps,kcar,kmod,kndx,11 ;f11=hires sine wave
afm1 oscil afm,1/p3,18
afm2=afm1*400
krtl=sqrt(2)/2*cos(kpan)+sin(kpan) ;constant power panning
krtr=sqrt(2)/2*cos(kpan)-sin(kpan)
al=afm2*krtl
ar=afm2*krtr
outs al,ar
garvbsig=garvbsig+(afm2*krvb)
endin
;========================================
;INSTRUMENT 6 - Clicky Filter Sweep w/pan
;========================================
instr 6
aclk=p3*4.3
apls oscil 7000,aclk,2
abp butterbp apls,2500,200
abp=abp*3
anoise oscil abp,aclk,8
kswp line 1800,p3,180
afilt reson anoise,kswp,20
afilt2 oscil afilt,1/p3,10
kpan line 0,p3*.8,1
afilt2=afilt2*.05
outs afilt2*kpan,afilt2*(1-kpan)
garvbsig=garvbsig+(afilt2*.02)
gasig=gasig+(afilt2*.6)
endin
;================================
;INSTRUMENT 8 - Cascade Harmonics
;================================
instr 8
i1=p6
i2=2*p6
i3=3*p6
i4=4*p6
ampenv linen p5,30,p3,30
a1 oscili ampenv,p4,20
a2 oscili ampenv,p4+i1,20
a3 oscili ampenv,p4+i2,20
a4 oscili ampenv,p4+i3,20
a5 oscili ampenv,p4+i4,20
a6 oscili ampenv,p4-i1,20
a7 oscili ampenv,p4-i2,20
a8 oscili ampenv,p4-i3,20
a9 oscili ampenv,p4-i4,20
asnd=(a1+a2+a3+a4+a5+a6+a7+a8+a9)/9
outs a1+a3+a5+a7+a9,a2+a4+a6+a8
garvbsig=garvbsig+(asnd*.85)
endin
;==========================
;==========================
instr 9
krt=p6 ;frq controls the randh & clk osc
isd=p4 ;value of the seed for randh UG
krnd randh 10000,krt,isd ;noise input to S&H
kclk oscil 100,krt,14 ;kclk clocks the S&H
ksh samphold krnd, kclk ;S&H
a2 oscil 2, 100,11
a4 reson a2,ksh,50
a3 oscil a4,1/p3,10 ;f10=ADSR - a3 is the output
a3=a3*.15
kpan oscil 1,.14,17
asig1=a3*kpan
asig2=a3*(1-kpan)
outs asig1,asig2
garvbsig=garvbsig+(a3*.4)
endin
;========================
;INSTR 99 - Global Reverb
;========================
instr 99
a1 reverb2 garvbsig,p4,p5
outs a1,a1
garvbsig=0
endin
;=======================
;INSTR 98 - Global Delay
;=======================
instr 98
a1 delay gasig,p4 ;delay=1.25
a2 delay gasig,p4*2 ;delay=2.50
outs a1,a2
gasig=0
endin